Περιεχόμενα
Δείκτης 🔎︎

# SFDialogs. Υπηρεσία Διάλογος

Η υπηρεσία Dialog συμβάλλει στη διαχείριση των διαλόγων που δημιουργούνται με την Επεξεργασία διαλόγου της Basic. Κάθε παρουσία της τρέχουσας κλάσης αντιπροσωπεύει ένα ενιαίο πλαίσιο διαλόγου που εμφανίζεται στον χρήστη.

Ένα πλαίσιο διαλόγου μπορεί να εμφανιστεί σε αναγκαστικές ή μη αναγκαστικές καταστάσεις.

Στη αναγκαστική κατάσταση, εμφανίζεται το πλαίσιο και η εκτέλεση της διαδικασίας μακροεντολής αναστέλλεται μέχρι να πατηθεί ένα από τα κουμπιά Εντάξει ή Ακύρωση. Στο μεταξύ, οι ενέργειες χρήστη που εκτελούνται στο πλαίσιο μπορούν να ενεργοποιήσουν συγκεκριμένες ενέργειες.

Στη μη αναγκαστική κατάσταση, το πλαίσιο διαλόγου "επιπλέει" στην επιφάνεια εργασίας του χρήστη και η εκτέλεση της διαδικασίας μακροεντολής συνεχίζεται κανονικά. Ένα μη αναγκαστικό παράθυρο διαλόγου κλείνει όταν τερματίζεται με τη μέθοδο Terminate(), ή όταν τελειώσει η συνεδρία του LibreOffice. Το πλήκτρο κλεισίματος παραθύρου είναι ανενεργό σε μη αναγκαστικούς διαλόγους.

Ένα πλαίσιο διαλόγου εξαφανίζεται από τη μνήμη μετά τον ρητό τερματισμό του.

Η υπηρεσία SFDialogs.Dialog σχετίζεται στενά με την υπηρεσία SFDialogs.DialogControl.

## Κλήση και χρήση της υπηρεσίας

Πριν τη χρήση της υπηρεσίας Dialog, πρέπει να φορτωθεί ή να εισαχθεί η βιβλιοθήκη ScriptForge:

• Οι μακροεντολές Basic απαιτούν τη φόρτωση της βιβλιοθήκης ScriptForge χρησιμοποιώντας την ακόλουθη πρόταση:
GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
• Τα σενάρια Python απαιτούν εισαγωγή από την ενότητα scriptforge:
από το scriptforge import CreateScriptService

Η υπηρεσία Dialog καλείται μέσω της μεθόδου CreateScriptService. Απαιτεί τρία ορίσματα θέσης για να καθορίσετε το πλαίσιο διαλόγου για ενεργοποίηση:

Container (περιέκτης): "GlobalScope" για προεγκατεστημένες βιβλιοθήκες ή όνομα παραθύρου όπως ορίζεται από την υπηρεσία ScriptForge.UI. Η προεπιλεγμένη τιμή κενής συμβολοσειράς "" αντιπροσωπεύει το τρέχον έγγραφο.

Library (Βιβλιοθήκη): Το όνομα με διάκριση πεζών-κεφαλαίων μιας βιβλιοθήκης που περιέχεται στον περιέκτη. Η προεπιλεγμένη τιμή είναι "Standard" (Τυπική).

DialogName (Όνομα διαλόγου): Μια συμβολοσειρά με διάκριση πεζών-κεφαλαίων που προσδιορίζει το παράθυρο διαλόγου.

The examples below in Basic and Python display the dlgConsole dialog that belongs to the ScriptForge shared library:

          Dim oDlg As Object, lButton As Long
          Dim Container As String, Library As String, DialogName As String
          Set oDlg = CreateScriptService("SFDialogs.Dialog", "GlobalScope", "ScriptForge", "dlgConsole")
          '... η αρχικοποίηση των στοιχείων ελέγχου πηγαίνει εδώ...
          lButton = oDlg.Execute()
          'Προεπιλεγμένη κατάσταση = Modal (Αναγκαστική)
          If lButton = oDlg.OKBUTTON Then
          '... Στοιχεία ελέγχου διεργασίας και κάντε ό,τι χρειάζεται εδώ
          End If
          oDlg.Terminate()

Ή χρησιμοποιώντας Python:

        dlg = CreateScriptService('SFDialogs.Dialog', 'GlobalScope', 'ScriptForge', 'dlgConsole')
        # ... η αρχικοποίηση των στοιχείων ελέγχου πηγαίνει εδώ...
        rc = dlg.Execute()
        # Η προεπιλεγμένη κατάσταση είναι Modal (αναγκαστική)
        if rc == dlg.OKBUTTON:
            # ... Επεξεργαστείτε τα στοιχεία ελέγχου και κάντε ό,τι χρειάζεται εδώ
        dlg.Terminate()

Use the string "GlobalScope" as the container argument when the dialog is stored either in My Macros & Dialogs or in Application Macros & Dialogs.

## Retrieving the Dialog instance that triggered a dialog event

An instance of the Dialog service can be retrieved via the SFDialogs.DialogEvent service, provided that the dialog was initiated with the Dialog service. In the example below, oDlg contains the Dialog instance that triggered the dialog event.

        Sub aDialogEventHander(ByRef poEvent As Object)
            Dim oDlg As Object
            Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
            ' ...
        End Sub

Or using Python:

        def control_event_handler(event: uno):
            dlg = CreateScriptService("SFDialogs.DialogEvent", event)
            # ...

Note that in the previous examples, the prefix "SFDialogs." may be omitted when deemed appropriate.

## Handling exceptions in event handlers

When creating an event handler for dialog events it is good practice to handle errors inside the subroutine itself. For instance, suppose the event handler below is called when the mouse button is pressed in the dialog window.

        Sub OnMouseButtonPressed(ByRef oEvent As Object)
        On Local Error GoTo Catch
            Dim oDialog As Object
            oDialog = CreateScriptService("DialogEvent", oEvent)
            ' Process the event
            Exit Sub
        Catch:
            MsgBox SF_Exception.Description
            SF_Exception.Clear
        End Sub

Call SF_Exception.Clear if you do not want the error to propagate after the dialog execution ended.

In Python use native try/except blocks for exception handling as shown below:

        def on_mouse_button_pressed(event=None):
            try:
                dlg = CreateScriptService("DialogEvent", event)
                # Process the event
            except Exception as e:
                # The object "bas" is an instance of the Basic service
                bas.MsgBox(str(e))

## Ιδιότητες

Όνομα | Μόνο για ανάγνωση | Τύπος | Περιγραφή
--- | --- | --- | ---
OKBUTTON | Ναι | Integer | Value (Τιμή) = 1. Πατήθηκε πλήκτρο OK (Εντάξει).
CANCELBUTTON | Ναι | Integer | Value (Τιμή) = 0. Πατήθηκε πλήκτρο Ακύρωσης.
Caption | Όχι | String | Καθορίστε τον τίτλο του διαλόγου.
Height | Όχι | Long | Καθορίστε το ύψος του πλαισίου διαλόγου.
Modal | Ναι | Boolean | Καθορίζει εάν το πλαίσιο διαλόγου εκτελείται αυτήν τη στιγμή σε λειτουργία modal (αναγκαστική).
Name | Ναι | String | Το όνομα του διαλόγου
Page | Όχι | Integer | Ένα παράθυρο διαλόγου μπορεί να έχει πολλές σελίδες που μπορεί να διασχίσει ο χρήστης βήμα προς βήμα. Η ιδιότητα Page (Σελίδα) του αντικειμένου διαλόγου ορίζει ποια σελίδα του διαλόγου είναι ενεργή.
Visible | Όχι | Boolean | Καθορίστε εάν το πλαίσιο διαλόγου είναι ορατό στην επιφάνεια εργασίας. Από προεπιλογή δεν είναι ορατό μέχρι να εκτελεστεί η μέθοδος Execute() και να είναι ορατή στη συνέχεια.
XDialogModel | Ναι | UNO object | Το αντικείμενο UNO που αντιπροσωπεύει το μοντέλο διαλόγου. Ανατρέξτε στο XControlModel και UnoControlDialogModel στην τεκμηρίωση της διασύνδεσης προγραμματισμού εφαρμογών (API) για λεπτομερείς πληροφορίες.
XDialogView | Ναι | UNO object | Το αντικείμενο UNO που αντιπροσωπεύει την προβολή διαλόγου. Ανατρέξτε στα XControl και UnoControlDialog στην τεκμηρίωση της διασύνδεσης προγραμματισμού εφαρμογών (API) για λεπτομερείς πληροφορίες.
Width | Όχι | Long | Καθορίστε το πλάτος του πλαισίου διαλόγου.

## Ιδιότητες συμβάντος

Επιστρέφει μια συμβολοσειρά URI με αναφορά στο σενάριο που ενεργοποιήθηκε από το συμβάν. Διαβάστε τις προδιαγραφές του στην προδιαγραφή URI σεναρίου πλαισίου.

Όνομα | Μόνο για ανάγνωση | Περιγραφή IDE Basic
--- | --- | ---
OnFocusGained | Ναι | Κατά τη λήψη της εστίασης
OnFocusLost | Ναι | Κατά τη απώλεια της εστίασης
OnKeyPressed | Ναι | Με το πλήκτρο πατημένο
OnKeyReleased | Ναι | Με το πλήκτρο απελευθερωμένο
OnMouseDragged | Ναι | Το ποντίκι μετακινήθηκε κατά το πάτημα του πλήκτρου
OnMouseEntered | Ναι | Το ποντίκι εντός
OnMouseExited | Ναι | Το ποντίκι εκτός
OnMouseMoved | Ναι | Το ποντίκι μετακινήθηκε
OnMousePressed | Ναι | Με πατημένο το πλήκτρο του ποντικιού
OnMouseReleased | Ναι | Με απελευθερωμένο το πλήκτρο του ποντικιού

| Μέθοδοι |
--- | --- | ---
Activate Center Controls | EndExecute Execute GetTextsFromL10N | Resize SetPageManager Terminate

## Activate

Ρυθμίστε την εστίαση στην τρέχουσα παρουσία του Dialog (Διάλογος). Επιστροφή True εάν η εστίαση ήταν επιτυχής.

Αυτή η μέθοδος καλείται από ένα συμβάν διαλόγου ή ελέγχου, ή όταν εμφανίζεται ένα παράθυρο διαλόγου σε μη αναγκαστική λειτουργία.

### Σύνταξη:

svc.Activate(): bool

### Παράδειγμα:

          Dim oDlg As Object
          Set oDlg = CreateScriptService(,, "myDialog")
          oDlg.Execute()
          ' ...
          oDlg.Activate()

Τα παραδείγματα Python και LibreOffice Basic υποθέτουν και τα δύο ότι το παράθυρο διαλόγου είναι αποθηκευμένο στη βιβλιοθήκη Standard (Τυπική)του τρέχοντος εγγράφου.

         dlg = CreateScriptService(,,'myDialog')
         dlg.Execute()
         # ...
         dlg.Activate()

## Center

Κεντράρει την τρέχουσα παρουσία διαλόγου στη μέση ενός γονικού παραθύρου. Χωρίς ορίσματα, η μέθοδος κεντράρει το παράθυρο διαλόγου στη μέση του τρέχοντος παραθύρου.

Επιστρέφει True όταν είναι επιτυχές.

### Σύνταξη:

svc.Center(opt Parent: obj): bool

### Παράμετροι:

Parent (Γονικό): Ένα προαιρετικό αντικείμενο που μπορεί να είναι είτε…

- ένα αντικείμενο διαλόγου ScriptForge

- ένα αντικείμενο εγγράφου ScriptForge (Calc, Βάση, ...)

### Παράδειγμα:

##### Σε Basic

         Sub TriggerEvent(oEvent As Object)
             Dim oDialog1 As Object, oDialog2 As Object, lExec As Long
             Set oDialog1 = CreateScriptService("DialogEvent", oEvent) ' Το παράθυρο διαλόγου που προκάλεσε το συμβάν
             Set oDialog2 = CreateScriptService("Dialog", ...) ' Άνοιγμα δεύτερου διαλόγου
             oDialog2.Center(oDialog1)
             lExec = oDialog2.Execute()
             Select Case lExec
                 ...
         End Sub

##### Σε Python

         def triggerEvent(event: uno):
           dlg1 = CreateScriptService('DialogEvent.Dialog', συμβάν) # Το παράθυρο διαλόγου που προκάλεσε το συμβάν
           dlg2 = CreateScriptService('Dialog', ...) # Άνοιγμα δεύτερου διαλόγου
           dlg2.Center(dlg1)
           rc = dlg2.Execute()
           if rc is False:
             # ...

## Controls

Επιστροφή είτε:

- του καταλόγου με τα στοιχεία ελέγχου που περιέχονται στο παράθυρο διαλόγου

- μια παρουσίας κλάσης DialogControl με βάση το όνομά της

### Σύνταξη:

svc.Controls(): str[0..*]

svc.Controls(controlname: str): svc

### Παράμετροι:

ControlName (Όνομα ελέγχου): Ένα έγκυρο όνομα ελέγχου ως συμβολοσειρά με διάκριση πεζών-κεφαλαίων. Εάν δεν υπάρχει, ο κατάλογος ονομάτων ελέγχου επιστρέφεται ως πίνακας μηδενικής βάσης.

### Παράδειγμα:

          Dim myDialog As Object, myList As Variant, myControl As Object
          Set myDialog = CreateScriptService("SFDialogs.Dialog", , "Standard", "Dialog1")
          myList = myDialog.Controls()
          Set myControl = myDialog.Controls("myTextBox")

         dlg = CreateScriptService('SFDialogs.Dialog','', 'Standard', 'Dialog1')
         ctrls = dlg.Controls()
         ctrl = dlg.Controls('myTextBox')

## EndExecute

Τερματίζει την εμφάνιση ενός αναγκαστικού διαλόγου και επιστρέφει το όρισμα ως επιστρεφόμενη τιμή για την τρέχουσα εκτελούμενη ενέργεια Execute().

Το EndExecute() (Τέλος εκτέλεσης) περιέχεται συνήθως στην επεξεργασία μιας μακροεντολής που ενεργοποιείται από ένα συμβάν διαλόγου ή ελέγχου.

### Σύνταξη:

svc.EndExecute(returnvalue: int)

### Παράμετροι:

returnvalue (τιμή επιστροφής): Η τιμή μεταβιβάστηκε στην τρέχουσα μέθοδο Execute().

### Παράδειγμα:

Χρήση του LibreOffice Basic:

          Sub OnEvent(poEvent As com.sun.star.lang.EventObject)
              Dim oDlg As Object
              Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
              oDlg.EndExecute(ReturnValue := 25)
          End Sub

Χρησιμοποιώντας Python:

         from com.sun.star.lang import EventObject
         def on_event(event: EventObject):
             dlg = CreateScriptService("SFDialogs.DialogEvent", event)
             dlg.EndExecute(25)

Πάνω από το com.sun.star.lang.EventObject οι αναφορές είναι προαιρετικές. Τέτοιοι σχολιασμοί βοηθούν στον προσδιορισμό της διεπαφής προγραμματισμού εφαρμογών (API) του LibreOffice.

## Execute

Εμφάνιση του πλαισίου διαλόγου και, όταν είναι αναγκαστικό, περιμένετε τον τερματισμό του από τον χρήστη. Η επιστρεφόμενη τιμή είναι είτε:

- 0 : πατήθηκε το πλήκτρο Cancel (Ακύρωση)

- 1 : πατήθηκε το πλήκτρο OK

- Διαφορετικά, ο διάλογος σταμάτησε με μια δήλωση EndExecute() που εκδόθηκε από ένα συμβάν διαλόγου ή ελέγχου

Για παράθυρα διαλόγου που δεν είναι αναγκαστικά, η μέθοδος επιστρέφει πάντα 0 και η εκτέλεση της μακροεντολής συνεχίζεται.

### Σύνταξη:

svc.Execute(modal: bool = True): int

### Παράμετροι:

modal (αναγκαστικό): False όταν ο διάλογος δεν είναι αναγκαστικός. Προεπιλογή = True.

### Παράδειγμα:

Σε αυτό το παράδειγμα Basic, ο διάλογος myDialog αποθηκεύεται στη βιβλιοθήκη Standard (Τυπική) του τρέχοντος εγγράφου.

          Dim oDlg As Object, lReturn As Long
          Set oDlg = CreateScriptService("SFDialogs.Dialog", , , "myDialog")
          lReturn = oDlg.Execute(Modal := False)
          Select Case lReturn
              ' ...
          End Select

Αυτός ο κώδικας Python εμφανίζει τον αναγκαστικό διάλογο DlgConvert από την κοινόχρηστη βιβλιοθήκη Basic Euro.

         dlg = CreateScriptService("SFDialogs.Dialog", 'GlobalScope', 'Euro', "DlgConvert")
         rc = dlg.Execute()
         if rc == dlg.CANCELBUTTON:
             # ...

## GetTextsFromL10N

Αντικαθιστά όλες τις σταθερές συμβολοσειρές κειμένου σε ένα παράθυρο διαλόγου από τις μεταφρασμένες εκδόσεις τους που βασίζονται σε μια παρουσία υπηρεσίας L10N. Αυτή η μέθοδος μεταφράζει τις ακόλουθες συμβολοσειρές:

- Ο τίτλος του διαλόγου.

- Η λεζάντα των ακόλουθων τύπων ελέγχου: Button (πλήκτρο), CheckBox (πλαίσιο ελέγχου), FixedLine (σταθερή γραμμή), FixedText (σταθερό κείμενο), GroupBox (πλαίσιο ομάδας)και RadioButton (πλήκτρο επιλογής).

- Στατικές συμβολοσειρές σε πλαίσια καταλόγου και σύνθετα πλαίσια.

- Η συμβουλή οθόνης ή το κείμενο βοήθειας που εμφανίζεται όταν το ποντίκι τοποθετείται πάνω από το στοιχείο ελέγχου.

Η μέθοδος επιστρέφει True εάν είναι επιτυχής.

Για να δημιουργήσετε έναν κατάλογο με μεταφράσιμες συμβολοσειρές σε ένα παράθυρο διαλόγου, χρησιμοποιήστε τη μέθοδο AddTextsFromDialog από την υπηρεσία L10N.

### Σύνταξη:

svc.GetTextsFromL10N(l10n: svc): bool

### Παράμετροι:

l10n: Μια παρουσία υπηρεσίας L10N από την οποία θα ανακτηθούν μεταφρασμένες συμβολοσειρές.

### Παράδειγμα:

Το παρακάτω παράδειγμα φορτώνει μεταφρασμένες συμβολοσειρές και τις εφαρμόζει στο παράθυρο διαλόγου "MyDialog".

##### Σε Basic

         oDlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         oDlg.GetTextsFromL10N(myPO)
         oDlg.Execute()

##### Σε Python

         dlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         dlg.GetTextsFromL10N(myPO)
         dlg.Execute()

Ανατρέξτε στη σελίδα βοήθειας Υπηρεσία L10N για να μάθετε περισσότερα σχετικά με τον τρόπο χειρισμού των αρχείων PO και POT.

## Resize

Μετακινεί την επάνω αριστερή γωνία ενός διαλόγου σε νέες συντεταγμένες ή/και τροποποιεί τις διαστάσεις του. Όλες οι αποστάσεις εκφράζονται σε 1/100 mm. Χωρίς ορίσματα, η μέθοδος επαναφέρει τις αρχικές διαστάσεις. Επιστρέφεται True εάν η αλλαγή μεγέθους ήταν επιτυχής.

### Σύνταξη:

svc.Resize(opt Left: num, opt Top: num, opt Width: num, opt Height: num): bool

### Παράμετροι:

Left (Αριστερά): η οριζόντια απόσταση από την επάνω αριστερή γωνία

Top (Επάνω): η κατακόρυφη απόσταση από την επάνω αριστερή γωνία

Width (Πλάτος): το πλάτος του ορθογωνίου που περιέχει το παράθυρο διαλόγου

Height (Ύψος): το ύψος του ορθογωνίου που περιέχει το παράθυρο διαλόγου

Τα αρνητικά ή τα ορίσματα που λείπουν παραμένουν αμετάβλητα

### Παράδειγμα:

##### Σε Basic

         oDialog.Resize(1000, 2000, Height := 6000) ' Το πλάτος δεν έχει αλλάξει

##### Σε Python

Με Python:

         oDialog.Resize(1000, 2000, Height = 6000) # Το πλάτος δεν έχει αλλάξει

## SetPageManager

Defines which controls in a dialog are responsible for switching pages, making it easier to manage the Page property of a dialog and its controls.

Dialogs may have multiple pages and the currently visible page is defined by the Page dialog property. If the Page property is left unchanged, the default visible page is equal to 0 (zero), meaning that no particular page is defined and all visible controls are displayed regardless of the value set in their own Page property.

When the Page property of a dialog is changed to some other value such as 1, 2, 3 and so forth, then only the controls whose Page property match the current dialog page will be displayed.

By using the SetPageManager method it is possible to define four types of page managers:

- List box or combo box: in this case, each entry in the list box or combo box corresponds to a page. The first item refers to Page 1, the second items refers to Page 2 and so on.

- Group of radio buttons: defines a group of radio buttons that will control which page is visible.

- Sequence of buttons: defines a set of buttons, each of which corresponding to a dialog page. This can be used to emulate a tabbed interface by placing buttons side by side in the dialog.

- Previous/Next buttons: defines which buttons in the dialog that will be used to navigate to the Previous/Next page in the dialog.

It is possible to use more than one page management mechanism at the same time.

This method is supposed to be called just once before calling the Execute method. Subsequent calls are ignored.

If successful this method returns True.

### Σύνταξη:

svc.SetPageManager(pilotcontrols: str = "", tabcontrols: str = "", wizardcontrols: str = "", opt lastpage: int): bool

### Παράμετροι:

pilotcontrols: a comma-separated list of ListBox, ComboBox or RadioButton control names used as page managers. For RadioButton controls, specify the name of the first control in the group to be used.

tabcontrols: a comma-separated list of button names that will be used as page managers. The order in which they are specified in this argument corresponds to the page number they are associated with.

wizardcontrols: a comma-separated list with the names of two buttons that will be used as the Previous/Next buttons.

lastpage: the number of the last available page. It is recommended to specify this value when using the Previous/Next page manager.

### Παράδειγμα:

Consider a dialog with three pages. The dialog has a ListBox control named "aPageList" that will be used to control the visible page. Additionally, there are two buttons named "btnPrevious" and "btnNext" that will be used as the Previous/Next buttons in the dialog.

##### Σε Basic

        oDialog.SetPageManager(PilotControls := "aPageList", _
                               WizardControls := "btnPrevious,btnNext", _
                               LastPage := 3)
        oDialog.Execute()

##### Σε Python

        dlg.SetPageManager(pilotcontrols="aPageList",
                           wizardcontrols="btnPrevious,btnNext",
                           lastpage=3)
        dlg.Execute()

## Terminate

Τερματίστε την υπηρεσία Dialog για την τρέχουσα παρουσία. Επιστρέφει True εάν ο τερματισμός ήταν επιτυχής.

### Σύνταξη:

svc.Terminate(): bool

### Παράδειγμα:

Στα παρακάτω παραδείγματα Basic και Python ανοίγουν οι μη αναγκαστικοί διάλογοι DlgConsole και dlgTrace. Αποθηκεύονται αντίστοιχα στις κοινόχρηστες βιβλιοθήκες ScriptForge και Access2Base. Τα πλήκτρα κλεισίματος διαλόγου είναι απενεργοποιημένα και ο ρητός τερματισμός εκτελείται στο τέλος μιας εκτελούμενης διαδικασίας.

Σε αυτό το παράδειγμα, ένα πλήκτρο στην DlgConsole αντικαθιστά το κλείσιμο παραθύρου με αναστολή:

##### Σε Basic

         oDlg = CreateScriptService("SFDialogs.Dialog","GlobalScope","ScriptForge","DlgConsole")
         oDlg.Execute(modal:=False)
         Wait 5000
         oDlg.Terminate()

Με Python:

##### Σε Python

         from time import sleep
         dlg = CreateScriptService('SFDialogs.Dialog',"GlobalScope",'Access2Base',"dlgTrace")
         dlg.Execute(modal=False)
         sleep 5
         dlg.Terminate()

Όλες οι ρουτίνες ή αναγνωριστικά του ScriptForge στη Basic που έχουν το πρόθεμα χαρακτήρα υπογράμμισης "_" δεσμεύονται για εσωτερική χρήση. Δεν προορίζονται να χρησιμοποιηθούν σε μακροεντολές Basic ή σενάρια Python.

Σχετικά θέματα

Υπηρεσία SFDialogs.DialogControl

Υπηρεσία ScriptForge.UI